nixos-config/flake.nix

{
  description = "System config";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils.url = "github:numtide/flake-utils";

    nixos-hardware.url = "github:NixOS/nixos-hardware";

    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.flake-utils.follows = "flake-utils";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    deploy-rs = {
      url = "github:serokell/deploy-rs";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "flake-utils";
    };

    naersk = {
      url = "github:nix-community/naersk";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };

    sops = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    emacs-overlay = {
      url = "github:nix-community/emacs-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };

    hyprland = {
      url = "github:Hyprwm/Hyprland";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nil = {
      url = "github:oxalica/nil";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
      inputs.rust-overlay.follows = "rust-overlay";
    };

    nomachine = {
      url = "github:rytec-nl/nixpkgs/submit/add-nomachine-server";
    };

    ha-now-playing = {
      url = "git+https://git.datarift.nl/erwin/ha-now-playing.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
      inputs.naersk.follows = "naersk";
      inputs.rust-overlay.follows = "rust-overlay";
      inputs.pre-commit-hooks.follows = "pre-commit-hooks";
    };

    pamedia = {
      url = "git+https://git.datarift.nl/erwin/pamedia-rs.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "flake-utils";
      inputs.naersk.follows = "naersk";
    };

    sunshine = {
      url = "git+https://git@git.datarift.nl/erwin/sunshine.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };
  };

  outputs =
    { self
    , sops
    , ha-now-playing
    , pamedia
    , deploy-rs
    , ...
    } @ inputs:
      with inputs; let
        machines = import ./machines inputs;
        defSystem = system: baseConfig:
          nixpkgs.lib.nixosSystem {
            system = "${system}";
            modules = [
              { _module.args.inputs = inputs; }
              { _module.args.self-overlay = self.overlays.default; }
              ({ ... }: {
                imports =
                  builtins.attrValues self.nixosModules
                  ++ [
                    {
                      nix.nixPath = [ "nixpkgs=${nixpkgs}" ];
                      nixpkgs =
                        let
                          nomachine-pkgs = import inputs.nomachine {
                            inherit system;
                            config.allowUnfree = true;
                          };
                        in
                        {
                          overlays = [
                            self.overlays.default
                            ha-now-playing.overlays.${system}
                            pamedia.overlays.${system}
                            inputs.emacs-overlay.overlay
                            inputs.nil.overlays.default
                            (_final: _prev: {
                              nomachine = nomachine-pkgs.nomachine;
                            })
                          ] ++ nixpkgs.lib.optional (system == "aarch64-linux")
                            (_final: super: {
                              makeModulesClosure = x:
                                super.makeModulesClosure (x // { allowMissing = true; });
                            });

                          config.allowUnfree = true;
                        };
                    }

                    baseConfig
                    home-manager.nixosModules.home-manager
                    { home-manager.useUserPackages = true; }
                  ];

                system.configurationRevision = nixpkgs.lib.mkIf (self ? rev) self.rev;
                nix.registry.nixpkgs.flake = nixpkgs;
              })
              sops.nixosModules.sops
              inputs.sunshine.nixosModules.sunshine
              inputs.hyprland.nixosModules.default
            ];
          };
      in
      {

        overlays.default = import ./overlays;
        # overlay = final: prev: {
        #   unstable = import nixpkgs {
        #     system = "x86_64-linux";
        #     config.allowUnfree = true;
        #   };
        # };

        nixosModules = builtins.listToAttrs (map
          (x: {
            name = x;
            value = import (./modules + "/${x}");
          })
          (builtins.attrNames (builtins.readDir ./modules)));

        nixosConfigurations = builtins.listToAttrs (map
          (machine: {
            name = machine;
            value = defSystem (machines.${machine}.system or "x86_64-linux") {
              imports = [
                machines.${machine}.config
              ];
            };
          })
          (builtins.attrNames machines));

        deploy.nodes = {
          gitea = {
            hostname = "10.0.0.201";
            # fastConnection = true;

            profiles = {
              system = {
                sshUser = "root";
                path = deploy-rs.lib.x86_64-linux.activate.nixos self.nixosConfigurations.gitea;
                user = "root";
              };
            };
          };
        };
      }
      // (flake-utils.lib.eachSystem [ "aarch64-linux" "x86_64-linux" ])
        (
          system:
          let
            pkgs = import nixpkgs {
              inherit system;
              overlays = [
                self.overlays.default
                ha-now-playing.overlays.${system}
                pamedia.overlays.${system}
              ];
              config = {
                allowUnsupportedSystem = true;
                allowUnfree = true;
              };
            };
            # pkgs = nixpkgs.legacyPackages.${system};
          in
          {
            packages = flake-utils.lib.flattenTree {
              rofi-wayland = pkgs.rofi-wayland;
              nix-plugins = pkgs.nix-plugins;
              backscrub = pkgs.backscrub;
              bl3auto = pkgs.bl3auto;
              commitgpt = pkgs.commitgpt;
            };

            apps = {
              rofi-wayland = flake-utils.lib.mkApp { drv = packages.rofi-wayland; };
              nix-plugins = flake-utils.lib.mkApp { drv = packages.nix-plugins; };
              backscrub = flake-utils.lib.mkApp { drv = packages.backscrub; };
            };

            checks = {
              pre-commit-check = pre-commit-hooks.lib.${system}.run {
                src = ./.;
                hooks = {
                  nixpkgs-fmt.enable = true;
                  deadnix.enable = true;
                  statix.enable = true;
                  black.enable = true;
                  shellcheck = {
                    enable = true;
                    types_or = [ "executable" ];
                  };
                  shfmt.enable = true;
                };
              };

            } // deploy-rs.lib.${system}.deployChecks self.deploy;

            devShells.default = with pkgs;
              mkShell {
                inherit (self.checks.${system}.pre-commit-check) shellHook;
                name = "dotfiles";
                nativeBuildInputs = [
                  pkgs.sops
                  ssh-to-pgp
                  ssh-to-age
                  age
                  nodejs-18_x
                  nodePackages.typescript-language-server
                  nodePackages.yaml-language-server
                  nodePackages.vscode-css-languageserver-bin
                  python3Packages.python-lsp-server
                  statix
                  multimarkdown
                  pngcrush
                  nix-diff
                  popsicle
                  nix-prefetch
                  nix-prefetch-scripts
                  nix-prefetch-github
                  nix-prefetch-docker
                  nixos-install-tools
                  deploy-rs.packages.${system}.deploy-rs

                  eww-wayland
                ];
              };

            formatter = pkgs.nixpkgs-fmt;
          }
        );
}