nixos-config/overlays/default.nix

final: prev: {
  backscrub = prev.pkgs.callPackage ../pkgs/backscrub {
    inherit (prev.pkgs)
      gcc
      cmake
      opencv
      curl
      stdenv
      git
      tensorflow-lite
      flatbuffers
      ;
  };

  ddccontrol-db = prev.ddccontrol-db.overrideAttrs (
    _finalAttrs: prevAttrs: {
      patches = (prevAttrs.patches or [ ]) ++ [ ./ddccontrol-db/0001-add-del41d9.patch ];
    }
  );

  git-repo-go = prev.pkgs.callPackage ../pkgs/git-repo-go { };

  peakperf = prev.pkgs.callPackage ../pkgs/peakperf {
    enableCuda = false; # peakperf needs cuda-samples, which is not available in current CUDA. CUDA 11 is broken due to CVEs in freeimage
  };
  mapshot = prev.pkgs.callPackage ../pkgs/mapshot { };

  factorio = prev.factorio.override { versionsJson = ./factorio.json; };

  python312 = prev.python312.override {
    packageOverrides = _pyfinal: pyprev: {
      wxpython = pyprev.wxpython.overrideAttrs (_old: {
        version = "4.2.2";

        src = final.fetchPypi {
          pname = "wxPython";
          version = "4.2.2";
          hash = "sha256-XbywZQ9n/cLFlleVolX/qj17CfsUmqjaLQ2apE444ro=";
        };
      });
    };
  };
  python312Packages = final.python312.pkgs;

  python311 = prev.python311.override {
    packageOverrides = _pyfinal: pyprev: {
      wxpython = pyprev.wxpython.overrideAttrs (_old: {
        version = "4.2.2";

        src = final.fetchPypi {
          pname = "wxPython";
          version = "4.2.2";
          hash = "sha256-XbywZQ9n/cLFlleVolX/qj17CfsUmqjaLQ2apE444ro=";
        };
      });
    };
  };
  python311Packages = final.python311.pkgs;
}