nixos-config/overlays/default.nix

inputs: _final: prev: {
  backscrub = prev.pkgs.callPackage ../pkgs/backscrub {
    inherit (prev.pkgs)
      gcc
      cmake
      opencv
      curl
      stdenv
      git
      tensorflow-lite
      flatbuffers
      ;
  };

  ddccontrol-db = prev.ddccontrol-db.overrideAttrs (
    _finalAttrs: prevAttrs: {
      patches = (prevAttrs.patches or [ ]) ++ [ ./ddccontrol-db/0001-add-del41d9.patch ];
    }
  );

  git-repo-go = prev.pkgs.callPackage ../pkgs/git-repo-go { };

  peakperf = prev.pkgs.callPackage ../pkgs/peakperf {
    enableCuda = false; # peakperf needs cuda-samples, which is not available in current CUDA. CUDA 11 is broken due to CVEs in freeimage
  };
  mapshot = prev.pkgs.callPackage ../pkgs/mapshot { };

  factorio = prev.factorio.override { versionsJson = ./factorio.json; };

  pds = prev.pkgs.callPackage ../pkgs/pds { };
  pdsadmin = prev.pkgs.callPackage ../pkgs/pdsadmin { };

  ghostty = inputs.ghostty.packages.${prev.system}.ghostty;

  caddy-cloudflare = prev.caddy.withPlugins {
    plugins = [ "github.com/caddy-dns/cloudflare@v0.0.0-20240703190432-89f16b99c18e" ];
    hash = "sha256-jCcSzenewQiW897GFHF9WAcVkGaS/oUu63crJu7AyyQ=";
  };
}