nixos-config/pkgs/incus-ui/default.nix

{
  lib,
  stdenv,
  fetchFromGitHub,
  fetchYarnDeps,
  nodejs,
  prefetch-yarn-deps,
  fixup-yarn-lock,
  yarn,
  gnused,
  rsync,
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "incus-ui";
  version = "0.8";

  src = fetchFromGitHub {
    owner = "canonical";
    repo = "lxd-ui";
    rev = finalAttrs.version;
    hash = "sha256-oD/GPm84oFXHcZ8vTUzNgQinrHwNuvpeVjsrp8ibIZY=";
  };

  offlineCache = fetchYarnDeps {
    yarnLock = "${finalAttrs.src}/yarn.lock";
    hash = "sha256-hRZ0vbksxnUv4XMrbhP2PI94UYYzwrydJHSx+uf+MbI=";
  };

  patches = [
    ./ui-canonical-0001-Branding.patch
    ./ui-canonical-0002-Update-navigation.patch
    ./ui-canonical-0003-Update-certificate-generation.patch
    ./ui-canonical-0004-Remove-external-links.patch
    ./ui-canonical-0005-Remove-Canonical-image-servers.patch
    ./ui-canonical-0006-Remove-version-check.patch
  ];

  nativeBuildInputs = [
    nodejs
    prefetch-yarn-deps
    fixup-yarn-lock
    yarn
  ];

  configurePhase = ''
    runHook preConfigure

    ${gnused}/bin/sed -e "s/devlxd/guestapi/g" \
                      -e "s/dev\/lxd/dev\/incus/g" \
                      -e "s/LXD/Incus/g" \
                      -e "s/Lxd/Incus_/g" \
                      -e "s/lxd/incus/g" -i src/*/*.ts* src/*/*/*.ts* src/*/*/*/*.ts*

    export HOME=$(mktemp -d)
    yarn config --offline set yarn-offline-mirror "$offlineCache"
    fixup-yarn-lock yarn.lock
    yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
    patchShebangs node_modules
    cp ${./favicon-32x32.png} public/assets/img/favicon-32x32.png

    runHook postConfigure
  '';

  buildPhase = ''
    runHook preBuild

    yarn --offline build

    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall

    mkdir -p $out
    ${rsync}/bin/rsync -a build/ui/ $out/

    runHook postInstall
  '';

  meta = with lib; {
    description = "Easy and accessible container and virtual machine management. A browser interface for LXD";
    homepage = "https://github.com/canonical/lxd-ui";
    license = licenses.gpl3;
    maintainers = with maintainers; [ ];
    platforms = platforms.linux;
  };
})