nixos-config/flake.nix

{
  description = "System config";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils.url = "github:numtide/flake-utils";

    ha-now-playing = {
      url = "git+ssh://git@git.datarift.nl/erwin/ha-now-playing.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "flake-utils";
    };

    pamedia = {
      url = "git+ssh://git@git.datarift.nl/erwin/pamedia.git?ref=main";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "flake-utils";
    };
  };

  outputs = { self, ha-now-playing, pamedia, ... }@inputs:
    with inputs;
    let

      defSystem = system: baseConfig:
        nixpkgs.lib.nixosSystem {
          system = "${system}";
          modules = [
            { _module.args.inputs = inputs; }
            { _module.args.self-overlay = self.overlay; }
            { _module.args.pamedia-overlay = pamedia.overlay; }
            { _module.args.ha-now-playing-overlay = ha-now-playing.overlay; }
            ({ ... }: {
              imports = builtins.attrValues self.nixosModules ++ [
                {
                  nix.nixPath = [ "nixpkgs=${nixpkgs}" ];
                  nixpkgs.overlays = [
                    self.overlay
                    ha-now-playing.overlay
                    pamedia.overlay
                  ];
                }

                baseConfig
                home-manager.nixosModules.home-manager
                { home-manager.useUserPackages = true; }
              ];

              system.configurationRevision = nixpkgs.lib.mkIf (self ? rev) self.rev;
              nix.registry.nixpkgs.flake = nixpkgs;
            })
          ];
        };

    in
    {
      overlay = import ./overlays;
      # overlay = final: prev: {
      #   unstable = import nixpkgs {
      #     system = "x86_64-linux";
      #     config.allowUnfree = true;
      #   };
      # };

      nixosModules = builtins.listToAttrs (map
        (x: {
          name = x;
          value = import (./modules + "/${x}");
        })
        (builtins.attrNames (builtins.readDir ./modules)));

      nixosConfigurations = {
        vm1 = defSystem "x86_64-linux" {
          imports = [
            (import (./machines/vm1/configuration.nix) { inherit self; })
          ];
        };
        vm2 = defSystem "x86_64-linux" {
          imports = [
            (import (./machines/vm2/configuration.nix) { inherit self; })
          ];
        };

        loki = defSystem "x86_64-linux" {
          imports = [
            (import (./machines/loki/configuration.nix) { inherit self; })
          ];
        };

      };
    } //
    (flake-utils.lib.eachSystem [ "aarch64-linux" "x86_64-linux" ])
      (system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              self.overlay
              ha-now-playing.overlay
              pamedia.overlay
            ];
            config = {
              allowUnsupportedSystem = true;
              allowUnfree = true;
            };
          };
        in
        rec {
          packages = flake-utils.lib.flattenTree {
            rofi-wayland = pkgs.rofi-wayland;
            # pamedia = pkgs.pamedia;
          };

          apps = {
            rofi-wayland = flake-utils.lib.mkApp { drv = packages.rofi-wayland; };
            # pamedia = flake-utils.lib.mkApp { drv = packages.pamedia; };
          };
        }
      );
}