Add gitu

flake.nix

@@ -231,6 +231,7 @@
           packages = {
             incus-ui = pkgs.callPackage ./pkgs/incus-ui { };
             openfga = pkgs.callPackage ./pkgs/openfga { };
+            gitu = pkgs.callPackage ./pkgs/gitu { };
           };
 
           devShells.default =

home-manager/modules/git/default.nix

@@ -176,6 +176,9 @@ in
       };
     };
 
-    home.packages = [ pkgs.git-credential-manager ];
+    home.packages = [
+      pkgs.git-credential-manager
+      pkgs.gitu
+    ];
   };
 }

overlays/default.nix

@@ -44,4 +44,5 @@ _final: prev: {
 
   incus-ui = prev.pkgs.callPackage ../pkgs/incus-ui { };
   openfga = prev.pkgs.callPackage ../pkgs/openfga { };
+  gitu = prev.pkgs.callPackage ../pkgs/gitu { };
 }

pkgs/gitu/default.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  libgit2,
+  openssl,
+  zlib,
+  stdenv,
+  darwin,
+  git,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "gitu";
+  version = "0.5.4";
+
+  src = fetchFromGitHub {
+    owner = "altsem";
+    repo = "gitu";
+    rev = "v${version}";
+    hash = "sha256-a4hNgEizxanYE3XuHSCmbV6CkOqhXkznP3Sp0KLFFQs=";
+  };
+
+  cargoHash = "sha256-+CA3UG32oZedzRbt7b0wOlhH/subuym4BCL5SMNzrr8=";
+
+  nativeBuildInputs = [
+    pkg-config
+    git
+  ];
+
+  buildInputs = [
+    libgit2
+    openssl
+    zlib
+  ] ++ lib.optionals stdenv.isDarwin [ darwin.apple_sdk.frameworks.Security ];
+
+  meta = with lib; {
+    description = "A TUI Git client inspired by Magit";
+    homepage = "https://github.com/altsem/gitu";
+    changelog = "https://github.com/altsem/gitu/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ];
+    mainProgram = "gitu";
+  };
+}