final: prev: {
  backscrub = prev.pkgs.callPackage ../pkgs/backscrub {
    inherit (prev.pkgs)
      gcc
      cmake
      opencv
      curl
      stdenv
      git
      tensorflow-lite
      flatbuffers
      ;
  };

  ddccontrol-db = prev.ddccontrol-db.overrideAttrs (
    _finalAttrs: prevAttrs: {
      patches = (prevAttrs.patches or [ ]) ++ [ ./ddccontrol-db/0001-add-del41d9.patch ];
    }
  );

  git-repo-go = prev.pkgs.callPackage ../pkgs/git-repo-go { };

  peakperf = prev.pkgs.callPackage ../pkgs/peakperf {
    enableCuda = false; # peakperf needs cuda-samples, which is not available in current CUDA. CUDA 11 is broken due to CVEs in freeimage
  };
  mapshot = prev.pkgs.callPackage ../pkgs/mapshot { };

  factorio = prev.factorio.override { versionsJson = ./factorio.json; };

  python312 = prev.python312.override {
    packageOverrides = _pyfinal: pyprev: {
      pyscard = pyprev.pyscard.overrideAttrs (_old: {
        version = "2.2.0";

        src = final.fetchFromGitHub {
          owner = "LudovicRousseau";
          repo = "pyscard";
          rev = "refs/tags/2.2.0";
          hash = "sha256-yZeP4Tcxnwb2My+XOsMtj+H8mNIf6JYf5tpOVUYjev0=";
        };

        postPatch = ''
                substituteInPlace pyproject.toml \
                  --replace-fail 'requires = ["setuptools","swig"]' 'requires = ["setuptools"]'
          substituteInPlace setup.py --replace-fail "pkg-config" "$PKG_CONFIG"
                    substituteInPlace src/smartcard/scard/winscarddll.c \
                      --replace-fail "libpcsclite.so.1" \
                                "${final.lib.getLib final.pcsclite}/lib/libpcsclite${final.stdenv.hostPlatform.extensions.sharedLibrary}"
        '';

        preCheck = null;
        disabledTests = [ ];

      });
    };
  };
  python312Packages = final.python312.pkgs;

  python311 = prev.python311.override {
    packageOverrides = _pyfinal: pyprev: {

      pyscard = pyprev.pyscard.overrideAttrs (_old: {
        version = "2.2.0";

        src = final.fetchFromGitHub {
          owner = "LudovicRousseau";
          repo = "pyscard";
          rev = "refs/tags/2.2.0";
          hash = "sha256-yZeP4Tcxnwb2My+XOsMtj+H8mNIf6JYf5tpOVUYjev0=";
        };

        postPatch = ''
                substituteInPlace pyproject.toml \
                  --replace-fail 'requires = ["setuptools","swig"]' 'requires = ["setuptools"]'
          substituteInPlace setup.py --replace-fail "pkg-config" "$PKG_CONFIG"
                    substituteInPlace src/smartcard/scard/winscarddll.c \
                      --replace-fail "libpcsclite.so.1" \
                                "${final.lib.getLib final.pcsclite}/lib/libpcsclite${final.stdenv.hostPlatform.extensions.sharedLibrary}"
        '';

        preCheck = null;
        disabledTests = [ ];

      });
    };
  };
  python311Packages = final.python311.pkgs;
}