nixos-config/users/erwin/home.nix

{ pkgs, config, lib, inputs, self-overlay, ... }:
with lib; let
  cfg = config.eboskma.users.erwin;
  bt = config.eboskma.bluetooth;
in
{
  config =
    mkIf cfg.home {
      home-manager.users.erwin = {
        _module.args.flake-inputs = inputs;

        programs.home-manager.enable = true;
        programs.command-not-found.enable = true;

        services.blueman-applet.enable = bt.enable;

        home.username = "erwin";
        home.homeDirectory = "/home/erwin";
        home.sessionVariables = {
          EDITOR = "${config.home-manager.users.erwin.eboskma.programs.emacs.package}/bin/emacsclient -c";
        };

        nixpkgs.config.allowUnfree = true;

        home.stateVersion = "21.11";

        eboskma = {
          programs = {
            alacritty.enable = false;
            atuin.enable = true;
            bat.enable = true;
            cargo = {
              enable = true;
              settings = {
                registries.crates-io = {
                  protocol = "sparse";
                };
              };
            };

            dropbox.enable = true;
            dunst.enable = false;
            emacs = {
              enable = true;
              # package = with pkgs; ((emacsPackagesFor emacsPgtk).emacsWithPackages (epkgs: [ epkgs.emacsql epkgs.emacsql-sqlite ]));
              package =
                let
                  emacs29 = pkgs.emacsPgtk.overrideAttrs (_: {
                    version = "29.0.90+gitc0ab4e9ca932";
                    src = pkgs.fetchFromSavannah {
                      repo = "emacs";
                      rev = "c0ab4e9ca9326c472ff1d9d01a0e3966f20fda27";
                      sha256 = "HxwVIVPIPMpp551Uo2qzcSSk2cM1N4YDBH6p3V2P4Rg=";
                    };
                  });
                in
                emacs29.override {
                  treeSitterPlugins = builtins.attrValues (filterAttrs (_: isDerivation) pkgs.tree-sitter-grammars);
                };

              daemon = true;
            };
            electron = {
              enable = true;
              wayland = true;
            };
            firefox = {
              enable = true;
              work = config.eboskma.base.work;
            };
            fish.enable = true;
            foot = {
              enable = true;
              server = false;
            };
            git = {
              enable = true;
              name = "Erwin Boskma";
              email = "erwin@datarift.nl";
              # signingKey = "EE7ADEFE1D943C7B";
              signingKey = "~/.ssh/id_ed25519";
              signingKeyFormat = "ssh";
            };
            gpg.enable = true;
            mpd.enable = true;
            neovim.enable = true;
            nushell.enable = true;
            obs-studio.enable = true;
            rclone = {
              enable = true;
              mounts = [
                {
                  remote = "org-roam";
                  local = "/home/erwin/org-roam";
                  remoteConfig = {
                    type = "sftp";
                    host = "zh2088.rsync.net";
                    user = "zh2088";
                    key_file = "~/.ssh/id_ed25519-rsync.net";
                    md5sum_command = "md5 -r";
                    sha2sum_command = "sha1 -r";
                  };
                }
              ];
            };
            rofi = {
              enable = true;
              package = pkgs.rofi-wayland;
              terminal = config.home-manager.users.erwin.wayland.windowManager.sway.config.terminal;
            };
            vscode.enable = true;
            solvespace.enable = true;
            ssh.enable = true;
            starship.enable = true;
            sway.enable = true;
            swaynotificationcenter.enable = true;
            tea = {
              enable = true;
              settings = {
                logins = [
                  {
                    name = "datarift";
                    url = "https://git.datarift.nl";
                    token = "abc";
                    default = true;
                    ssh_host = "git.datarift.nl";
                    user = "erwin";
                  }
                ];
              };
            };
            tmux.enable = true;
            waybar.enable = true;
            zathura.enable = true;
            zellij = {
              enable = true;
              copyCommand = "${pkgs.wl-clipboard}/bin/wl-copy";
            };
          };
        };

        home.packages = with pkgs;
          [
            atool
            bitwarden
            blink1-tool
            bottom
            dbeaver
            easyeffects
            fd
            ffmpeg_5-full
            freecad
            gnome.nautilus
            horizon-eda
            imagemagick
            imv
            iotop
            (jetbrains.clion.override { jdk = pkgs.jetbrains.jdk; })
            kicad
            larynx
            libnotify
            libreoffice-fresh
            minio-client
            mpv
            nomachine-client
            nordzy-cursor-theme
            pamedia
            pass
            povray
            quintom-cursor-theme
            procs
            prusa-slicer
            qgis
            ripgrep
            scid-vs-pc
            signal-desktop
            solo2-cli
            steam
            steamcmd
            steam-tui
            super-slicer-latest
            units
            unzip
            xdg-utils
            wl-clipboard
            zeal
          ]
          ++ (with gst_all_1; [ gstreamer gstreamer.dev gst-plugins-base gst-plugins-good gst-plugins-bad gst-plugins-ugly gst-libav gst-vaapi ]);

        xdg = {
          enable = true;
          mime.enable = true;
          mimeApps = {
            enable = true;
            defaultApplications = {
              "x-scheme-handler/http" = "firefox.desktop";
              "x-scheme-handler/https" = "firefox.desktop";
              "x-scheme-handler/chrome" = "firefox.desktop";
              "x-scheme-handler/terminal" = "${cfg.terminal}.desktop";
              "text/html" = "firefox.desktop";
              "application/x-extension-htm" = "firefox.desktop";
              "application/x-extension-html" = "firefox.desktop";
              "application/x-extension-shtml" = "firefox.desktop";
              "application/xhtml+xml" = "firefox.desktop";
              "application/x-extension-xhtml" = "firefox.desktop";
              "application/x-extension-xht" = "firefox.desktop";
              "application/pdf" = "org.pwmt.zathura-pdf-mupdf.desktop";
            };
            associations = {
              added = {
                "image/jpeg" = "imv.desktop";
                "image/png" = "imv.desktop";
                "image/gif" = "imv.desktop";
                "application/zip" = "org.gnome.FileRoller.desktop";
              };
            };
          };
          userDirs = {
            enable = true;
            createDirectories = true;
          };
        };

        i18n.inputMethod = {
          enabled = "fcitx5";
          fcitx5.addons = with pkgs; [ fcitx5-m17n fcitx5-gtk fcitx5-configtool ];
        };

        gtk = {
          enable = true;
          theme = {
            name = "Arc-Dark";
            package = pkgs.arc-theme;
          };

          iconTheme = {
            name = "Papirus-Dark";
            package = pkgs.papirus-icon-theme;
          };

          gtk3 = {
            bookmarks = [
              "file:///home/erwin/workspace"
            ];
            extraConfig = {
              gtk-application-prefer-dark-theme = 1;
              gtk-cursor-theme-name = "Nordzy-cursors";
            };
          };

          gtk4.extraConfig = {
            gtk-application-prefer-dark-theme = 1;
            gtk-cursor-theme-name = "Nordzy-cursors";
          };
        };

        imports = [
          {
            nixpkgs.overlays = [
              self-overlay
              inputs.ha-now-playing.overlays.${pkgs.system}
              inputs.pamedia.overlays.${pkgs.system}
              inputs.emacs-overlay.overlay
            ];
          }
          ../../modules/options
        ] ++ (map (mod: (../../home-manager/modules + "/${mod}")) (builtins.attrNames (builtins.readDir ../../home-manager/modules)));
      };


      # OBS control websocket
      networking.firewall.allowedTCPPorts = [ 4455 ];

      programs.steam.enable = true;
      programs.bandwhich.enable = true;
      programs.noisetorch.enable = true;

      services.ddccontrol.enable = true;

      programs.wireshark = {
        enable = true;
        package = pkgs.wireshark;
      };
      users.groups.wireshark.members = [ "erwin" ];
    };
}